基 础 函 数 参 考

GUICtrlCreateCombo

创建下拉组合框(ComboBox)控件.

GUICtrlCreateCombo ( "文本", 左距, 顶距 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参 数

文本 组合列表框(ComboBox)控件显示的文本.
左距 控件左侧的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算左侧位置.
顶距 控件上方的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算顶部位置.
宽度 [可选参数] 控件的宽度(默认使用先前的宽度).
高度 [可选参数] 控件的高度(默认使用先前的高度).
样式 [可选参数] 控件的样式. 查看附录 GUI 控件样式表.

默认样式 (-1) : $CBS_DROPDOWN, $CBS_AUTOHSCROLL, $WS_VSCROLL
强制样式 : $WS_TABSTOP
扩展样式 [可选参数] 控件的扩展样式. 查看附录 扩展样式表.

返 回 值

成功: 返回控件标识符(控件ID).
失败: 返回 0.

备 注

要获得控件的值, 查看 GUICtrlRead.
设置或者修改控件信息, 参考 GUICtrlUpdate....

Windows XP/2003 系统会自动调整打开选择框控件的大小, 而在其它的 Windows 版本下则可以利用"高度"参数定义它的大小.

要在默认样式上添加新样式, 可使用 BitOr($GUI_SS_DEFAULT_COMBO, 新样式,...) 语句.

使用上面列出的值必须将 #include <ComboConstants.au3> 语句写入脚本中.

默认大小 $GUI_DOCKHEIGHT.

相 关 函 数

GUICoordMode (Option), GUICtrlSetData, GUICtrlUpdate..., GUIGetMsg

函 数 示 例


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $msg
    GUICreate("我的下拉组合框 GUI") ; 创建居中显示的 GUI 窗口

    GUICtrlCreateCombo("项目 1", 10, 10) ; 创建下拉组合框
    GUICtrlSetData(-1, "项目 2|项目 3", "项目 3") ; 添加其它项目并设置默认项目

    GUISetState()

    ; 运行 GUI, 直到 GUI 被关闭
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example

provider with jb51.net (unicode)