基 础 函 数 参 考

GUICtrlCreateInput

创建输入框(Input)控件.

GUICtrlCreateInput ( "文本", 左距, 顶距 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参 数

文本 控件显示的文本.
左距 控件左侧的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算左侧位置.
顶距 控件上方的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算顶部位置.
宽度 [可选参数] 控件的宽度(默认使用先前的宽度).
高度 [可选参数] 控件的高度(默认使用先前的高度).
样式 [可选参数] 控件的样式. 查看附录 GUI 控件样式表.

默认样式 ( -1) : $ES_LEFT, $ES_AUTOHSCROLL
强制样式s : $WS_TABSTOP only if no $ES_READONLY. $ES_MULTILINE is always reset.
扩展样式 [可选参数] 控件的扩展样式. 查看附录 扩展样式表.

返 回 值

成功: 返回控件标识符(控件ID).
失败: 返回 0.

备 注

要获得控件的值, 查看 GUICtrlRead.
设置或者修改控件信息, 参考 GUICtrlUpdate....

定义输入密码(输入字符将被星号隐藏)的输入框控件, 则请使用 $ES_PASSWORD 样式.

如果要让控件接受文件拖放, 添加 WS_EX_ACCEPTFILES 扩展样式到 GUICreate(),
并设置状态为 $GUI_DROPACCEPTED.
拖动多个文件会被 "|" 分割开, 可以使用 GuiCtrlRead 读取文件名称.

使用上面列出的值必须将 #include <EditConstants.au3> 语句写入脚本中.

默认大小 $GUI_DOCKHEIGHT.

相 关 函 数

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg, GUICtrlRead, GUICtrlCreateUpdown, GUICtrlSetLimit

函 数 示 例


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $file, $btn, $msg

    GUICreate("我的输入框 GUI", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1, 0x00000018); 接受拖动文件 WS_EX_ACCEPTFILES
    $file = GUICtrlCreateInput("", 10, 5, 300, 20)
    GUICtrlSetState(-1, $GUI_DROPACCEPTED)
    GUICtrlCreateInput("", 10, 35, 300, 20) ; 不接受拖动文件
    $btn = GUICtrlCreateButton("确定", 40, 75, 60, 20)

    GUISetState()

    $msg = 0
    While $msg <> $GUI_EVENT_CLOSE
        $msg = GUIGetMsg()
        Select
            Case $msg = $btn
                ExitLoop
        EndSelect
    WEnd

    MsgBox(4096, 0, "拖放文件: " & GUICtrlRead($file))
EndFunc   ;==>Example

provider with jb51.net (unicode)