基 础 函 数 参 考

GUICtrlCreateList

创建列表(List)控件.

GUICtrlCreateList ( "文本", 左距, 顶距 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参 数

文本 控件显示的文本.
左距 控件左侧的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算左侧位置.
顶距 控件上方的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算顶部位置.
宽度 [可选参数] 控件的宽度(默认使用先前的宽度).
高度 [可选参数] 控件的高度(默认使用先前的高度).
样式 [可选参数] 控件的样式. 查看附录 GUI 控件样式表.

默认样式 ( -1) : $LBS_SORT, $WS_BORDER, $WS_VSCROLL
强制样式 : $WS_TABSTOP, $LBS_NOTIFY
扩展样式 [可选参数] 控件的扩展样式. 查看附录 扩展样式表.

返 回 值

成功: 返回控件标识符(控件ID).
失败: 返回 0.

备 注

要获得控件的值, 查看 GUICtrlRead.
设置或者修改控件信息, 参考 GUICtrlUpdate....

列表项目可由 GUICtrlSetData 设置

要限制使用水平滚动条请使用 GUICtrlSetLimit

要在默认样式上添加新样式, 可使用 BitOr($GUI_SS_DEFAULT_LIST, 新样式,...) 语句.

使用上面列出的值必须将 #include <ListBoxConstants.au3> 语句写入脚本中.

默认大小 $GUI_DOCKAUTO 出现的大小和位置.

相 关 函 数

GUICoordMode (Option), GUICtrlSetData, GUICtrlSetLimit, GUICtrlUpdate..., GUIGetMsg

函 数 示 例


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $MESSAGE = "列表内的第一行文本"
    Local $add, $clear, $mylist, $close, $msg

    GUICreate("我的列表 GUI") ; 创建居中显示的 GUI 窗口

    $add = GUICtrlCreateButton("添加文本", 64, 32, 75, 25)
    $clear = GUICtrlCreateButton("清除文本", 64, 72, 75, 25)
    $mylist = GUICtrlCreateList("第二行文本", 160, 32, 160, 97)
    GUICtrlSetLimit(-1, 200) ; 限制水平滚动
    GUICtrlSetData(-1, $MESSAGE)
    $close = GUICtrlCreateButton("关闭按钮", 64, 160, 175, 25)

    GUISetState()

    $msg = 0
    While $msg <> $GUI_EVENT_CLOSE
        $msg = GUIGetMsg()

        Select
            Case $msg = $add
                GUICtrlSetData($mylist, "您按了 [ 添加文本 ] 按钮.|")
            Case $msg = $clear
                GUICtrlSetData($mylist, "")
            Case $msg = $close
                MsgBox(0, "", "关闭按钮被点击", 2)
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Example

provider with jb51.net (unicode)