基 础 函 数 参 考

GUICtrlCreateTab

创建标签页(Tab)控件.

GUICtrlCreateTab ( 左距, 顶距 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参 数

左距 控件左侧的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算左侧位置.
顶距 控件上方的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算顶部位置.
宽度 [可选参数] 控件的宽度(默认使用先前的宽度).
高度 [可选参数] 控件的高度(默认使用先前的高度).
样式 [可选参数] 控件的样式. 查看附录 GUI 控件样式表.

默认样式 ( -1) : 无.
强制样式 : $WS_TABSTOP, $WS_CLIPSIBLINGS
扩展样式 [可选参数] 控件的扩展样式. 查看附录 扩展样式表.

返 回 值

成功: 返回控件标识符(控件ID).
失败: 返回 0.

备 注

本函数只是创建标签(Tab)控件(容器), 其中的标签选项页项目还要使用 GUICtrlCreate... 创建.

设置或者修改控件信息, 参考 GUICtrlUpdate....

要在默认样式上添加新样式, 可使用 BitOr($GUI_SS_DEFAULT_TAB, 新样式,...) 语句.

要使用上方指定的值, 必须将 #include <TabConstants.au3> 语句写入脚本中.

默认大小为 $GUI_DOCKSIZE.

窗口只能创建一个标签页控件. 但使用脚本代码可以在标签页控件内创建多个窗口.

相 关 函 数

GUICtrlCreateTabItem, GUICoordMode (Option), GUICtrlCreate..., GUICtrlUpdate..., GUIGetMsg

函 数 示 例


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $msg

    GUICreate("我的标签选项卡 GUI") ; 创建居中显示的 GUI 窗口

    GUISetBkColor(0x00E0FFFF)
    GUISetFont(9, 300)

    GUICtrlCreateTab(10, 10, 200, 100)

    GUICtrlCreateTabItem ("标签 0")
    GUICtrlCreateLabel("标记0", 30, 80, 50, 20)
    GUICtrlCreateButton("确定0", 20, 50, 50, 20)
    GUICtrlCreateInput("默认项", 80, 50, 70, 20)

    GUICtrlCreateTabItem ("标签 ----1")
    GUICtrlCreateLabel("标记1", 30, 80, 50, 20)
    GUICtrlCreateCombo("", 20, 50, 60, 120)
    GUICtrlSetData(-1, "资源|数码弹头|拉里|乔恩|泰罗", "乔恩") ; 默认乔恩
    GUICtrlCreateButton("确定1", 80, 50, 50, 20)

    GUICtrlCreateTabItem ("标签 2")
    GUICtrlSetState(-1, $GUI_SHOW) ; 将首先显示 标签 2
    GUICtrlCreateLabel("标记2", 30, 80, 50, 20)
    GUICtrlCreateButton("确定2", 140, 50, 50)

    GUICtrlCreateTabItem ("") ; 结束选项卡项目定义

    GUICtrlCreateLabel("标记3", 20, 130, 50, 20)

    GUISetState()

    ; 运行 GUI, 直到 GUI 被关闭
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example

provider with jb51.net (unicode)