基 础 函 数 参 考

GUISetStyle

调整窗口样式.

GUISetStyle ( 样式 [,扩展样式 [, 句柄]] )

参 数

样式 指定窗口的显示样式. 见附录 GUI 控件样式表.

指定 -1 为不调整.
扩展样式 [可选参数] 指定窗口的扩展样式. 见下面 扩展样式表. 默认值(default) -1.
使用 -1 为不调整.
句柄 [可选参数] 由 GUICreate 函数返回的窗口句柄 (默认为先前使用的窗口).

返 回 值

成功: 返回 1.
失败: 返回 0.

备 注

不检查原样式值, 也不与以定义的控件互动. 这是因为设计者 responsability 用来处理兼容性.

相 关 函 数

GUIGetStyle

函 数 示 例


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $NewStyle = False, $Style, $Msg

    GUICreate("设置窗口样式", 260, 100)
    $Style = GUICtrlCreateButton("设置窗口样式", 45, 50, 150, 20)
    GUISetState()

    While 1
        $Msg = GUIGetMsg()
        Switch $Msg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $Style
                If Not $NewStyle Then
                    GUISetStyle(BitOR($WS_POPUPWINDOW, $WS_THICKFRAME), BitOR($WS_EX_CLIENTEDGE, $WS_EX_TOOLWINDOW))
                    GUICtrlSetData($Style, '取消样式')
                    $NewStyle = True
                Else
                    GUISetStyle(BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU), 0)
                    GUICtrlSetData($Style, '设置样式')
                    $NewStyle = False
                EndIf
            Case Else
        EndSwitch
    WEnd
EndFunc   ;==>Example

provider with jb51.net (unicode)