基 础 函 数 参 考

IniWriteSection

写配置文件(*.ini)的字段数据.

IniWriteSection ( "文件名", "字段", "数据" [, 索引] )

参 数

文件名 目标 .ini 文件名.
字段名 .ini 文件中的字段名.
数据 要写入的数据. 这些数据可以是字符串或数组.
如果数据是字符串, 则每对 关键字=值 必须由 @LF 分隔.
如果数据是数组, 则必须为二维数组,且第二维必须含有两个元素.
索引 [可选参数] 如果数据是数组, 此参数指定开始写入的数组索引.
默认为 1, 以便 IniReadSection() 的返回值可以立即使用.
对于手动创建的数组, 参数值可能需要依赖数组是如何建立的而有所不同.
如果数据是字串, 则忽略这个参数.

返 回 值

成功: 返回 1.
失败: 返回 0. 如果数据格式无效, 则 @error 被设置为 1.

备 注

标准 INI 文件结构如下:
[字段名]
关键字=值
如果文件不存在, 则创建. 任何目录不存在, 将不会被创建.
关键字和(或)字段将被添加到最后, 并且不按任何规则排序.
如果字段已存在, 数据将覆盖.

相 关 函 数

IniDelete, IniRead, IniReadSection, IniReadSectionNames, IniWrite, IniRenameSection

函 数 示 例


; 这将写 INI 文件, 并创建到桌面.
Local $sIni = @DesktopDir & "\AutoIt-Test.ini"

; 使用字符串作为输入创建一个新的字段.
Local $sData = "关键字1=值1" & @LF & "关键字2=值2" & @LF & "关键字3=值3"
IniWriteSection($sIni, "字段1", $sData)

; 使用数组作为输入创建一个新字段.
Local $aData1 = IniReadSection($sIni, "字段1") ; 读取上面刚刚写的.
For $i = 1 To UBound($aData1) - 1
    $aData1[$i][1] &= "-" & $i ; 更改一些数据
Next

IniWriteSection($sIni, "字段2", $aData1) ; 写入到一个新字段.

; 手动创建一个数组, 并使用它作为输入.
Local $aData2[3][2] = [["第1关键字", "第1值"],["第2关键字", "第2值"],["第3关键字", "第3值"]]
; 上面所做的数组元素从 0 开始, 需要告诉 IniWriteSection() 从元素 0 开始写入.
IniWriteSection($sIni, "字段3", $aData2, 0)

provider with jb51.net (unicode)